Place a bet at 2 tick below

[thonggruss]

Hi

I think someone already did it but i couldnt find it. Just wondering may i know how can i place a bet which is 2 tick below the displayed odd ?

i tried to find this in the help>using excel but i cant find anything....

thanks for your help

[GaryRussell]

There isn't a trigger for this, but I could create one. At the moment you'd have to create a VBA function to work out the required odds.

[GaryRussell]

I've created some functions to work out the offset odds.

In the Excel macro editor create a new module and insert the following code.

In column R you can use the plusTicks or minusTicks function.
eg. =plusTicks(H5,2) to add 2 ticks to the lay odds

Function getPrevOdds(ByVal odds As Currency) As Currency
Dim oddsInc As Currency
Select Case odds
Case 1.01 To 2
oddsInc = 0.01
Case 2.02 To 3
oddsInc = 0.02
Case 3.05 To 4
oddsInc = 0.05
Case 4.1 To 6
oddsInc = 0.1
Case 6.2 To 10
oddsInc = 0.2
Case 10.5 To 20
oddsInc = 0.5
Case 21 To 30
oddsInc = 1
Case 32 To 50
oddsInc = 2
Case 55 To 100
oddsInc = 5
Case 110 To 1000
oddsInc = 10
End Select
If Math.Round(odds - oddsInc, 2) >= 1.01 Then
getPrevOdds = Math.Round(odds - oddsInc, 2)
Else
getPrevOdds = 1.01
End If
End Function

Function getNextOdds(ByVal odds As Currency) As Currency
Dim oddsInc As Currency
Select Case odds
Case 1 To 1.99
oddsInc = 0.01
Case 2 To 2.98
oddsInc = 0.02
Case 3 To 3.95
oddsInc = 0.05
Case 4 To 5.9
oddsInc = 0.1
Case 6 To 9.8
oddsInc = 0.2
Case 10 To 19.5
oddsInc = 0.5
Case 20 To 29
oddsInc = 1
Case 30 To 48
oddsInc = 2
Case 50 To 95
oddsInc = 5
Case 100 To 1000
oddsInc = 10
End Select
If Math.Round(odds + oddsInc, 2) <= 1000 Then
getNextOdds = Math.Round(odds + oddsInc, 2)
Else
getNextOdds = 1000
End If
End Function

Function plusTicks(odds As Currency, ticks As Byte) As Currency
Dim i As Byte
For i = 1 To ticks
odds = getNextOdds(odds)
Next
plusTicks = odds
End Function

Function minusTicks(odds As Currency, ticks As Byte) As Currency
Dim i As Byte
For i = 1 To ticks
odds = getPrevOdds(odds)
Next
minusTicks = odds
End Function

[thonggruss]

thanks Gary!

[allgreen]

Yes, thanks for that Gary - very handy!

[Ian]

Very useful, cheers.

[Shaun]

I was trying to make a formula for this but i get a message "Ambiguose name detected plusTicks"

=IF(AD5="","",IF(AA5=0,IF(Control!$V$6="BACK",minusTicks(O5,Control!Y6),plusTicks(O5,Control!Y6)),AA5))

[GaryRussell]

Send the spreadsheet to admin@gruss-software.co.uk and I'll have another look at it. It could be the VBA code isn't incorporated properly.

[Shaun]

on the way, Thanks

[Shaun]

I am still playing with some formulas so it may not work right.

[GaryRussell]

Just got round to having a look at your spreadsheet. It reports "ambiguous" because the same code is in module1 and module2 therefore it doesn't know which plusTicks function to use. Delete module2 by right clicking on it in the code editor and selecting "remove module2".

[Shaun]

Fairdinkum i can be a dick head at times, thanks for that

[Ian]

Are the ticks the same at Betdaq as Betfair ?

[GaryRussell]

Are the ticks the same at Betdaq as Betfair ?

No they are different. The following code should give you Betdaq odds.

Code: Select all

Function getPrevOdds(ByVal odds As Currency) As Currency
   Dim oddsInc As Currency
   Select Case odds
      Case 1.01 To 3
         oddsInc = 0.01
      Case 3.05 To 4
       oddsInc = 0.05
      Case 4.1 To 6
         oddsInc = 0.1
      Case 6.2 To 10
         oddsInc = 0.2
      Case 10.5 To 20
         oddsInc = 0.5
      Case 21 To 50
         oddsInc = 1
      Case 52 To 200
         oddsInc = 2
      Case 205 To 1000
         oddsInc = 5
   End Select
   If Math.Round(odds - oddsInc, 2) >= 1.01 Then
      getPrevOdds = Math.Round(odds - oddsInc, 2)
   Else
      getPrevOdds = 1.01
   End If
End Function

Function getNextOdds(ByVal odds As Currency) As Currency
   Dim oddsInc As Currency
   Select Case odds
      Case 1 To 2.99
         oddsInc = 0.01
      Case 3 To 3.95
       oddsInc = 0.05
      Case 4 To 5.9
         oddsInc = 0.1
      Case 6 To 9.8
         oddsInc = 0.2
      Case 10 To 19.5
         oddsInc = 0.5
      Case 20 To 49
         oddsInc = 1
      Case 50 To 198
         oddsInc = 2
      Case 200 To 1000
         oddsInc = 5
   End Select
   If Math.Round(odds + oddsInc, 2) <= 1000 Then
      getNextOdds = Math.Round(odds + oddsInc, 2)
   Else
      getNextOdds = 1000
   End If
End Function


[Ian]

Gary, thanks for this.